I might suggest that you write a short program to simulate the spectra. The problem with using real data is the amount of points (upwards of 32k) that make publishing CSV files of raw spectra unreasonable. Below is a quick attempt to give you what you are looking for. I apologize for those who do not use Mathematica; however I tried an Excel version and it became unwieldy very quickly.
I have three functions:
Clear[feature];
feature[shift_, n_, coupling_, intensity_] := Module[{},
Plus @@
Table[Binomial[n, k]*intensity/(n + 1)*
Cos[(x)*(shift + coupling (k - n/2))], {k, 0, n}]]
Clear[fid]
makefid[feature_, broadening_] := Module[{},
Exp[-broadening x] Plus @@ {feature}]
Clear[transform]
transform[fid_] := Module[{resolution = 4096, $y, $x},
$y = Re[Fourier[Table[fid, {x, 0, resolution, 0.1}]]];
$y = Take[$y, Round[Length[$y]/2]];
$x = Range[Length[$y]]/(resolution/(2 Pi));
Transpose@{$x, $y}
]
The function feature
creates a peak with a chemical shift as the first argument, the splitting as the second, the coupling constant (use 0.1 for starters) and the intensity (its integral). makefid
creates a simulated FID based on the feature that it is passed and transform
makes the spectrum. It can be used like this:
a = feature[1.2, 2, 0.1, 3];
b = feature[2, 0, 0.1, 3];
c = feature[4.1, 3, 0.1, 2];
fid = makefid[Plus @@ {a, b, c}, 0.01];
ListLinePlot[transform[fid], PlotRange -> {{0, 5}, All}]
The features {a,b,c}
are simulated ethyl acetate yielding the following spectrum:

The data you want is in transform[fid]
which can be exported as a CSV file:
Export["myfile.csv",transform[fid]]
Which will make it accessible to other software packages and you can perform your math lesson plan. To make sure this is working properly in Mathematica, we can make a function out of our data and numerically integrate the three peaks:
data = Interpolation[transform[fid]];
NIntegrate[data[x], {x, 0.9, 1.5}]
NIntegrate[data[x], {x, 1.5, 2.2}]
NIntegrate[data[x], {x, 3.7, 4.5}]
This produces areas of 0.32, 0.25, and 0.33, respectively, which is what we expected.