I believe have found a answer.
It's valid mathematically, make sense physically but I don't know if chemically is true.
I posted to community appreciation.
There we go!
The reactions
ionization of weak acid:
$$\ce{HA + H2O <=> H3O+ + A-}\qquad K_\ce{a}=\frac{\ce{[H3O+][A-]}}{\ce{[HA]}}
\tag{1}
\label{eq:KWeakAcid}$$
ionization of weak base:
$$\ce{B + H2O <=> BH+ + OH-}\qquad K_\ce{b}=\frac{\ce{[HB+][OH-]}}{\ce{[B]}}
\tag{2}
\label{eq:KWeakBase}$$
self-ionization of water:
$$\ce{2 H2O <=> H3O + OH-}\qquad K_\ce{w}=\ce{[H3O+][OH-]}
\tag{3}
\label{eq:KWater}$$
equilibrium of poorly soluble salt:
$$\ce{HBA <=> HB+ + A-}\qquad K_\ce{sp}=\ce{[HB+][A-]}
\tag{4}
\label{eq:KSalt}$$
Charge balance
$$\ce{[H3O+] + [HB+] = [OH-] + [A-]}\tag{5}\label{eq:ChangeBalance}$$
Mass balance
To mass balance we can use an expression based on amount of substance:
- Weak acid:
\begin{align}
{n_\ce{HA}}_\text{total}&={n_\ce{HA}}_\text{solution}+{n_\ce{A-}}_\text{solution}+{n_\ce{A-}}_\text{ppt}\\
C_\ce{HA}V_\ce{HA}&=\left(\ce{[HA] + [A-]}\right)V_\text{solution}+{n_\ce{A-}}_\text{ppt}\\
\\
\ce{[HA] + [A-]}&=\frac{C_\ce{HA}V_\ce{HA}-{n_\ce{A-}}_\text{ppt}}{V_\ce{HA}+V_\ce{B}}
\tag{6}
\label{eq:AcidMassBalance}\\
\end{align}
- Weak base:
\begin{align}
{n_\ce{B}}_\text{total}&={n_\ce{B}}_\text{solution}+{n_\ce{HB+}}_\text{solution}+{n_\ce{HB+}}_\text{ppt}\\
C_\ce{B}V_\ce{B}&=\left(\ce{[B] + [HB+]}\right)V_\text{solution}+{n_\ce{HB+}}_\text{ppt}\\
\\
\ce{[B] + [HB+]}&=\frac{C_\ce{B}V_\ce{B}-{n_\ce{HB+}}_\text{ppt}}{V_\ce{HA}+V_\ce{B}}
\tag{7}
\label{eq:BaseMassBalance}\\
\end{align}
The general equation
Combining ($\ref{eq:KWeakAcid}$) and ($\ref{eq:AcidMassBalance}$) equations we have:
$$\ce{[A-]}=\frac{K_\ce{a}}{\ce{[H3O+]}+K_\ce{a}}\frac{C_\ce{HA}V_\ce{HA}-{n_\ce{A-}}_\text{ppt}}{V_\ce{HA}+V_\ce{B}}
\tag{8}
\label{eq:Anion}$$
Combining ($\ref{eq:KWeakBase}$), ($\ref{eq:KWater}$) and ($\ref{eq:BaseMassBalance}$) equations we have:
$$\ce{[HB+]}=\frac{K_\ce{b}}{\displaystyle\frac{K_\ce{w}}{\ce{[H3O+]}}+K_\ce{b}}\frac{C_\ce{B}V_\ce{B}-
{n_\ce{HB+}}_\text{ppt}}{V_\ce{HA}+V_\ce{B}}
\tag{9}
\label{eq:Cation}$$
From ($\ref{eq:KSalt}$) equation we have ${n_\ce{HB+}}_\text{ppt}={n_\ce{A-}}_\text{ppt}=
n_\ce{HBA}=n_\text{ppt}=n$ and replacing ($\ref{eq:KWater}$), ($\ref{eq:Anion}$) and
($\ref{eq:Cation}$) equations in ($\ref{eq:ChangeBalance}$) equation we have:
$$\ce{[H3O+]} + \frac{K_\ce{b}}{\displaystyle\frac{K_\ce{w}}{\ce{[H3O+]}}+K_\ce{b}}
\frac{C_\ce{B}V_\ce{B}-n}{V_\ce{HA}+V_\ce{B}}
= \frac{K_\ce{w}}{\ce{[H3O+]}} + \frac{K_\ce{a}}{\ce{[H3O+]}+K_\ce{a}}
\frac{C_\ce{HA}V_\ce{HA}-n}{V_\ce{HA}+V_\ce{B}}
\tag{10}
\label{eq:TitrationCurve}$$
Besides that combining the ($\ref{eq:KSalt}$), ($\ref{eq:Anion}$) and ($\ref{eq:Cation}$) equations we have:
$$K_\ce{sp}=\overbrace{
\frac{K_\ce{b}}{\displaystyle\frac{K_\ce{w}}{\ce{[H3O+]}}+K_\ce{b}}\frac{C_\ce{B}V_\ce{B}-n}{V_\ce{HA}+V_\ce{B}}
}^{\ce{[HB+]}}
\overbrace{
\frac{K_\ce{a}}{\ce{[H3O+]}+K_\ce{a}}\frac{C_\ce{HA}V_\ce{HA}-n}{V_\ce{HA}+V_\ce{B}}
}^{\ce{[A-]}}
\tag{11}
\label{eq:Kppt}$$
Reproducing your data
If we ignore the poorly soluble salt formation, the ($\ref{eq:TitrationCurve}$)
equation is exactly the same which you deduced.
From your image we have
$V_\ce{HA} = \pu{1.00 L}$,
$C_{A} = \pu{0.01 mol L^{-1}}$,
$K_\ce{a} = \pu{2.0E-4}$,
$C_\ce{B} = \pu{0.20 mol L^{-1}}$,
$K_\ce{b} = \pu{2.0E-4}$, and
$K_\ce{w} = \pu{1.0E-14}$
for which the titration curve would be:
The plot of the concentrations of $\ce{[HB+]}$ and $\ce{[A-]}$ through titration would be:
Using the conductivity equation of the solution
$$\kappa_\ce{solution} = \lambda_\ce{A-}\ce{[A-]} + \lambda_\ce{HB+}\ce{[HB+]}
+ \lambda_\ce{H3O+}\ce{[H3O+]} + \lambda_\ce{OH-}\ce{[OH-]}
\tag{12}
\label{eq:ConductivitySolution}$$
and
$\lambda_\ce{A-} = \pu{ 90.0E-4 m^2 S mol^{-1}}$,
$\lambda_\ce{HB+} = \pu{172.0E-4 m^2 S mol^{-1}}$,
$\lambda_\ce{H3O+} = \pu{849.6E-4 m^2 S mol^{-1}}$, and
$\lambda_\ce{OH-} = \pu{398.0E-4 m^2 S mol^{-1}}$
from your image is possible to plot the conductivity curve:
If we look to contribution of each species to conductivity curve
we can understand its final shape.
Some considerations
To take account the formation of $\ce{HBA}$, suppose that $K_\ce{sp} = \pu{7.5E-5}$.
The $Q_\ce{sp}$ plot through titration would be:
While $Q_\ce{sp}<K_\ce{sp}$ we have $n=0$, because $\ce{[HB+][A-]}$ is less than
critical concentrations to start precipitation and the titration curve follows as usual.
When $Q_\ce{sp}=K_\ce{sp}$ we have the precipitation eminence and $n=0$.
When $Q_\ce{sp}>K_\ce{sp}$ I'm not sure what will happen.
The $V_\text{critical}$ in which $Q_\ce{sp}=K_\ce{sp}$ can be found graphical or analytical way.
The last way in not so easy, but I believe then can be done.
Personally I will use the graphical way.
Solving ($\ref{eq:TitrationCurve}$) equation to $V_\ce{B}$ (with $n=0$) we can write:
$$V_\ce{B}=\frac{V_\ce{HA}\left(\displaystyle\frac{K_\ce{w}}{\ce{[H3O+]}}-\ce{[H3O+] +
C_\ce{HA}\alpha_\ce{A-}}\right)}{C_\ce{B}\alpha_\ce{HB+} -
\left(\displaystyle\frac{K_\ce{w}}{\ce{[H3O+]}}-\ce{[H3O+]}\right)}
\tag{13}
\label{eq:Vtit}$$
Again, the ($\ref{eq:Vtit}$) equation is exactly the same which you deduced.
Solving ($\ref{eq:Kppt}$) to $V_\ce{B}$ (with $n=0$) we have:
$$V_\ce{B}=\displaystyle\frac{-\left[V_\ce{A}\left(2 -
\displaystyle\frac{C_\ce{HA}\alpha_\ce{A-}C_\ce{B}\alpha_\ce{HB+}}{K_\ce{sp}}\right)\right]-
\sqrt{\left[V_\ce{A}\left(2 - \displaystyle\frac{C_\ce{HA}\alpha_\ce{A-}C_\ce{B}\alpha_\ce{HB+}}
{K_\ce{sp}}\right)\right]^2 - 4V_\ce{HA}^2}}{2}
\tag{14}
\label{eq:Vcritical}$$
where
$${\alpha}_\ce{HB+}=\frac{K_\ce{b}}{\displaystyle\frac{K_\ce{w}}{\ce{[H3O+]}}+K_\ce{b}}$$
and
$${\alpha}_\ce{A-}=\frac{K_\ce{a}}{\ce{[H3O+]}+K_\ce{a}}$$
The $V_\ce{B}\ vs.\ \ce{pH}$ plot to ($\ref{eq:Vtit}$) and ($\ref{eq:Vcritical}$) equations
allows to find $V$ and $\ce{pH}$ for which the curves cut across each other.
Another (graphical) way could be the $Q_\ce{sp}$ plot.
Any way the values found are $\pu{45.20 mL}$ and $4.685$ respectively.
What happens with $\ce{pH}$ when $V_\ce{B}$ is greater than $V_\text{critical}$?
Some hypothesis can been proposed.
Hypothesis #1
$\ce{HBA}$ will precipitate and the titration curve don't be affected.
In this case the ($\ref{eq:Kppt}$) equation can be solved to $n$:
$$n=\displaystyle\frac{\left(n_\ce{HA}+n_\ce{B}\right)-
\sqrt{\left(-\left(n_\ce{HA}+n_\ce{B}\right)\right)^2 -
4\left(n_\ce{HA}n_\ce{B}-
\displaystyle\frac{K_\ce{sp}\left(V_\ce{HA}+V_\ce{B}\right)^2}
{{\alpha}_\ce{HB+}{\alpha}_\ce{A-}}\right)}}{2}
\tag{15}
\label{eq:nppt}$$
where $n_\ce{HA} = C_\ce{HA}V_\ce{HA}$ and $n_\ce{B} = C_\ce{B}V_\ce{B}$.
The ($\ref{eq:nppt}$) equation allows calculate the amount of precipitate is formed
given a $V_\ce{B}$ and $\ce{pH}$ value. But given a $V_\ce{B}$, what is $\ce{pH}$ value?
I believe that, if this hypothesis is true, the $\ce{pH}$ value can be calculated
from ($\ref{eq:TitrationCurve}$) equation and the titration curve don't be affected.
The the $n\ vs.\ V_\ce{B}$ plot of ($\ref{eq:nppt}$) equation is
and the $n\ vs.\ \ce{pH}$ plot of ($\ref{eq:nppt}$) equation is
The effect of precipitation can be seen in plots below.
The $\ce{[HB+]}$ and $\ce{[A-]}$ plot
The $Q_\ce{sp}$ plot
The plot of contribution of each species to conductivity
The total conductivity plot
Hypothesis #2
$\ce{HBA}$ don't precipitates and the $\ce{pH}$ rises.
In this case the $V_\ce{B}\ vs.\ \ce{pH}$ plot gives some clue.
The ($\ref{eq:Kppt}$) equation can be rearranged to give:
$$\ce{[H3O+]}^2 - \ce{[H3O+]}\left(
\frac{K_\ce{a}C_\ce{HA}V_\ce{HA}C_\ce{B}V_\ce{B}}
{K_\ce{sp}\left(V_\ce{HA}+V_\ce{B}\right)^2} - K_\ce{a} -
\frac{K_\ce{w}}{K_\ce{b}}\right) +
\frac{K_\ce{a}K_\ce{w}}{K_\ce{b}}=0
\tag{16}
\label{eq:TitrationCurvePpt}$$
Note that, using one of the roots from ($\ref{eq:TitrationCurvePpt}$) equation,
the $\ce{pH}$ jumps from $4.685$ to $9.315$ (see titration curve below) when
$V_\ce{B}=V_\text{critical}$ and, while $V_\ce{B}$ increases, the titration curve
is look like as usual.
Mathematically in this hypothesis no precipitate is formed, but the
solution cross the region where there should be precipitate.
The consequence this is the concentrations of $\ce{[A-]}$ and $\ce{[HB+]}$,
which depends on $\ce{pH}$ values, jumps too.
Hypothesis #3
$\ce{HBA}$ don't precipitates and the $\ce{pH}$ falls.
Again the $V_\ce{B}\ vs.\ \ce{pH}$ plot gives some clue.
Using the other root from ($\ref{eq:TitrationCurvePpt}$) equation, the titration curve
have a discontinuity at $V_\text{critical}$ and then the $\ce{pH}$ values falls
while $V_\ce{B}$ increases. No jumps, neither on concentrations or pH, are observed.
If hypothesis #3 is true, the plot of the concentrations of $\ce{[HB+]}$ and $\ce{[A-]}$
through titration is
the $Q_\ce{sp}$ plot is
the conductivity curve to each species
and finally the conductivity curve is
Addendum
To those interested follows the gnuplot code to produce these graphs. All equations needed to reproduce this answer are available.
The present code creates several graphs used in this answer but no all. Some of them are combination of two or more data sets or a graph from an equation available.
#
# Implements a lot of equations and create a couple of graphs showing what
# happens with pH, concentrations, conductivity, and Qsp when a poorly soluble
# salt is formed during a titration.
#
# To more details see the original question/answer
#
# Question: https://chemistry.stackexchange.com/q/117984/80491
# Answer: https://chemistry.stackexchange.com/a/118760/80491
#
# Author: GRSousaJr (https://chemistry.stackexchange.com/users/80491/grsousajr)
# gnuplot 5.2 patchlevel 7
#
# ========== INITIAL CONFIGURATION ===============================================
reset # return all graph-related options their default values
set encoding utf8 # selects a character encoding
# Save each graph as pdf file
set terminal pdfcairo size 8 in, 6 in font "Times New Roman,18" enhanced
# Colors of lines
set style line 1 lc "#e41a1c" # red
set style line 2 lc "#377eb8" # blue
set style line 3 lc "#4daf4a" # green
set style line 4 lc "#984ea3" # purple
# Margins
set lmargin screen 0.110 # left margin
set tmargin screen 0.940 # top margin
set bmargin screen 0.130 # bottom margin
set grid ls -1 lc "gray" # style for grid
set tics out nomirror # tics marks on axis
set samples 1000 # number of points to each curve
set dummy pH # "pH" as "x" for all plot-commands
unset key # turn-off the legend (key) exhibition
# ========== INPUT PARAMETERS ====================================================
# ---------- Weak acid (HA) ------------------------------------------------------
VA = 1.0 # L, HA volume (mandatory)
CA0 = 0.01 # mol/L, HA concentration (mandatory)
pKa = 3.69897 # Ka = 0.00020 (mandatory)
# ----------- Weak Base (B) ------------------------------------------------------
CB0 = 0.2 # mol/L, B concentration (mandatory)
pKb = 3.69897 # Kb = 0.00020 (mandatory)
VBmax = 120.0 # mL, B volume (optional)
# ----------- Poor soluble salt (HBA) --------------------------------------------
pptn = "True" # "True/False" (mandatory) indicates if occurs precipitation
Ksp = 7.5E-5 # HBA poor soluble salt (mandatory if pptn = "True")
# ----------- Solvent ------------------------------------------------------------
pKw = 14.0 # H2O self-ionization
# ----------- Conductivity constants ---------------------------------------------
array lambda[4]
lambda[1] = 90.00 # (E-4) A-
lambda[2] = 172.00 # (E-4) HB+
lambda[3] = 849.60 # (E-4) H+
lambda[4] = 398.00 # (E-4) OH-
# ========== DERIVATE PARAMETERS =================================================
# ---------- Equilibrium constants -----------------------------------------------
Ka = 10**(-pKa) # Ka from pKa
Kb = 10**(-pKb) # Kb from pKa
Kw = 10**(-pKw) # Kw from pKw
# ---------- Logical test to VBmax------------------------------------------------
if (!exists("VBmax")){
VBmax = 2.0*VA*CA0/CB0 # Double that required for neutralization
} else{
VBmax = VBmax/1000.0 # Converting mL to L
}
# ========== FUNCTIONS ===========================================================
# ---------- H+ and OH- concentrations (as a function of pH) ---------------------
H(pH) = 10**(-pH) # H+ from pH
OH(pH) = 10**(pH-14.0) # OH- from pH
# ---------- Ionization fractions (as a function of pH) --------------------------
aA(pH) = Ka/(H(pH) + Ka) # A-
aB(pH) = Kb/(Kw/H(pH) + Kb) # HB+
# ---------- B volume (as a function of pH) --------------------------------------
VB(pH) = (VA*(Kw/H(pH) - H(pH) + aA(pH)*CA0))/(aB(pH)*CB0 - (Kw/H(pH) - H(pH)))
# ---------- Amount of substance (as a function of pH) ---------------------------
nA = CA0*VA # HA
nB(pH) = CB0*VB(pH) # B
# Amount of precipitate formed
nppt(pH) = ((nA + nB(pH)) - sqrt((-(nA + nB(pH)))**2 - \
4*(nA*nB(pH) - (Ksp*(VA + VB(pH))**2/(aB(pH)*aA(pH))))))/2.0
# Logical test to know if precipitation must be taken account
if (pptn eq "True" ){
n(pH) = nppt(pH) <= 0 ? 0 : nppt(pH) # Disregards negative values of 'n'.
sufix = "_with_ppt"
} else {
n(pH) = 0 # No occurs precipitation
sufix = "_without_ppt"
}
# ---------- A- and HB+ concentrations (as a function of pH) ---------------------
CA(pH) = aA(pH)*(nA - n(pH))/(VA + VB(pH)) # [A-]
CB(pH) = aB(pH)*(nB(pH) - n(pH))/(VA + VB(pH)) # [HB+]
# ---------- Qsp (as a function of pH) -------------------------------------------
Qsp(pH) = CB(pH)*CA(pH)
# ---------- Individual and Total conductivities (as a function of pH) -----------
kappaA(pH) = lambda[1]*CA(pH)
kappaB(pH) = lambda[2]*CB(pH)
kappaH(pH) = lambda[3]*H(pH)
kappaOH(pH) = lambda[4]*OH(pH)
kappaSol(pH) = kappaA(pH) + kappaB(pH) + kappaH(pH) + kappaOH(pH)
# ---------- Initial and final pH ------------------------------------------------
pH0 = -log10((-Ka + sqrt(Ka**2 + 4*CA0*Ka))/2.0) # Initial pH
pHmax = pKw + log10((CA0*2*VA - CA0*VA)/(VA + VBmax)) # Estimate for pHmax at VBmax
#---------- Finding pHmax by iteration -------------------------------------------
while (VB(pHmax) > VBmax || VB(pHmax) < 0){
pHmax = pHmax - 0.0001
}
# ========== CREATING THE GRAPHS =================================================
# ---------- Titration curve -----------------------------------------------------
filename = "Titration_Curve" . sufix # Define a filename to pdf file
# Plotting using a data block (like a temp file)
set table $Titration_Data
plot [pH0:pHmax] 1000*VB(pH)
unset table
set xlabel "Volume of titrant / mL" # name for x-axis (the same to all plot-commands)
set ylabel "pH" # name for y-axis
set xrange [0:VBmax*1000] # VBmax in mL
set yrange [0:14] # pH 0 to 14
set xtics 10 # tics at each 10 mL
set ytics 1 # tics at each 1 pH unit
set output filename . ".pdf" # Create the pdf file
plot $Titration_Data using 2:1 with lines linestyle 1 linewidth 2
# ---------- Concentrations curves ------------------------------------------------
filename = "Concentrations_Curve" . sufix
set table $ConcB_Data
plot [pH0:pHmax] CB(pH)
unset table
set table $ConcA_Data
plot [pH0:pHmax] CA(pH)
unset table
set ylabel "Concentration / mol L^{–1}"
set yrange [0:CA0]
set ytics .001
set format y "%.3f" # number with 3 decimal places
# Labels
set label 1 "{/:Bold [HB^{+}]}" at 20.0, 0.003 tc ls 1 font ',20' offset 0,0.75
set label 2 "{/:Bold [A^{–}]}" at 05.0, 0.003 tc ls 2 font ',20' offset 0,0.75
set output filename . ".pdf"
plot \
$ConcB_Data u (1000*VB($1)):2 w l ls 1 lw 2 ,\
$ConcA_Data u (1000*VB($1)):2 w l ls 2 lw 2
unset for [i=1:2] label i # Clean the labels
unset format # Clean the format
# ---------- Individual conductivity curves --------------------------------------
filename = "Individual_Conductivity_Curve" . sufix
set table $ConducA_Data
plot [pH0:pHmax] kappaA(pH)
unset table
set table $ConducB_Data
plot [pH0:pHmax] kappaB(pH)
unset table
set table $ConducH_Data
plot [pH0:pHmax] kappaH(pH)
unset table
set table $ConducOH_Data
plot [pH0:pHmax] kappaOH(pH)
unset table
set ylabel "{/:Italic κ} / S m^{–1}"
set yrange [0:2]
set ytics .2
set format y "%.2f"
set label 1 "{/=24 {/:Italic κ}_{/=12 A^{–}}}" at 95, 0.70 center tc ls 1
set label 2 "{/=24 {/:Italic κ}_{/=12 HB^{+}}}" at 95, 1.50 center tc ls 2
set label 3 "{/=24 {/:Italic κ}_{/=12 H_{3}O^{+}}}" at 07, 0.90 center tc ls 3
set label 4 "{/=24 {/:Italic κ}_{/=12 OH^{–}}}" at 95, 0.15 center tc ls 4
set output filename . ".pdf"
plot \
$ConducA_Data u (1000*VB($1)):2 w l ls 1 lw 2 ,\
$ConducB_Data u (1000*VB($1)):2 w l ls 2 lw 2 ,\
$ConducH_Data u (1000*VB($1)):2 w l ls 3 lw 2 ,\
$ConducOH_Data u (1000*VB($1)):2 w l ls 4 lw 2
unset for [i=1:4] label i
unset format
# ---------- Total conductivity curves -------------------------------------------
filename = "Total_Conductivity_Curve" . sufix
set table $ConducSolution_Data
plot [pH0:pHmax] kappaSol(pH)
unset table
set yrange [0.75:3]
set ytics .25
set format y "%.2f"
set output filename . ".pdf"
plot $ConducSolution_Data u (1000*VB($1)):2 w l ls 1 lw 2
unset format
# ---------- Qsp curves ----------------------------------------------------------
filename = "Qsp_Curve" . sufix
set table $Qsp_Data
plot [pH0:pHmax] Qsp(pH)
unset table
set yrange [0:0.000100]
set ytics 0.00001
set ylabel "{/:Italic Q}_{sp}"
set format y "%h" # scientific notation format
set label 1 "{/:Bold {/:Italic Q}_{sp}}"\
at 32.0, 3.0E-5 tc ls 1 font ",20" offset 0,0.75
set label 2 "{/:Italic Q}_{sp} = {/:Italic K}_{sp}" \
at 70.0, Ksp tc ls 1 font ",20" offset 0,0.75
set output filename . ".pdf"
plot $Qsp_Data u (1000*VB($1)):2 w l ls 1 lw 2
